start to remove modules in favour of options

modules/features/nixos/home-manager.nix

@@ -0,0 +1,15 @@
+{ inputs, self, ... }: {
+  flake.nixosModules.global = { pkgs, lib, config, ... }: {
+    imports = [
+      inputs.home-manager.nixosModules.default
+    ];
+
+    options.features.nixos.home-manager.enable = lib.mkEnableOption "home-manager";
+
+    config.home-manager = lib.mkIf (config.features.nixos.home-manager.enable) {
+      useGlobalPkgs = true;
+      useUserPackages = true;
+      users.grey = self.homeModules.${config.networking.hostName};
+    };
+  };
+}

modules/features/nixos/nh.nix

@@ -0,0 +1,19 @@
+{ inputs, self, ... }: {
+  flake.nixosModules.global = { pkgs, config, lib, ... }: {
+    options.features.nixos.nh.enable = lib.mkOption {
+      type = lib.types.bool;
+      default = true;
+    };
+
+    config = lib.mkIf (config.features.nixos.nh.enable) {
+      environment.systemPackages = [
+        inputs.nh.packages.${pkgs.stdenv.hostPlatform.system}.default
+      ];
+
+      programs.nh = {
+        enable = true;
+        flake = "/home/grey/nixos";
+      };
+    };
+  };
+}

modules/features/nixos/stylix.nix

@@ -0,0 +1,15 @@
+{ inputs, self, ... }: {
+  flake.nixosModules.graphics = { pkgs, lib, config, ... }: {
+    imports = [
+      inputs.stylix.nixosModules.stylix
+    ];
+
+    options.features.nixos.stylix.enable = lib.mkEnableOption "stylix";
+
+    config = lib.mkIf (config.features.nixos.stylix.enable) {
+      stylix.enable = true;
+      stylix.image = builtins.path { path = "${self.outPath}/modules/hosts/${config.networking.hostName}/wallpaper.jpg"; };
+      stylix.polarity = "dark";
+    };
+  };
+}