{ inputs, self, ... }: {
  flake.nixosModules.global = { config, pkgs, lib, ... }: {
    options.features.shells.zsh = {
      enable = lib.mkEnableOption "zsh";
      antidote.enable = lib.mkEnableOption "antidote";
    };

    config = lib.mkIf (config.features.shells.zsh.enable) {
      programs.zsh.enable = true;
      users.defaultUserShell = pkgs.zsh;
      users.users."grey".shell = pkgs.zsh;
    };
  };

  flake.homeModules.global = { pkgs, osConfig, config, lib, ... }: {
    options.features.shells.zsh = {
      enable = lib.mkEnableOption "zsh";
      antidote.enable = lib.mkEnableOption "antidote";
    };

    config = (if (builtins.tryEval osConfig).success then (lib.mkIf (osConfig.features.shells.zsh.enable || config.features.shells.zsh.enable)) else (lib.mkIf (config.features.shells.zsh.enable))) {
      home.shell.enableZshIntegration = true;

      programs.kitty.shellIntegration.enableZshIntegration = true;

      programs.zsh = {
        enable = true;
        completionInit = "";
        antidote = (if (builtins.tryEval osConfig).success then (lib.mkIf (osConfig.features.shells.zsh.antidote.enable || config.features.shells.zsh.antidote.enable)) else (lib.mkIf (config.features.shells.zsh.antidote.enable))) {
          enable = true;
          plugins = [
            "getantidote/use-omz"
            "ohmyzsh/ohmyzsh path:lib"
            "ohmyzsh/ohmyzsh path:plugins/command-not-found"
            "ohmyzsh/ohmyzsh path:themes/nanotech.zsh-theme"
            "zsh-users/zsh-autosuggestions"
            "zdharma-continuum/fast-syntax-highlighting"
          ];
        };
      };
    };
  };
}