{ inputs, self, ... }: {
  flake.nixosModules.graphics = { config, pkgs, lib, ... }: {
    options.features.applications.gui.vscode.enable = lib.mkEnableOption "vscode";

    config = {
      environment.systemPackages = [ pkgs.vscode ];

      home-manager.sharedModules = lib.mkIf (config.features.applications.gui.vscode.enable) [
        {
          features.applications.gui.vscode.enable = lib.mkDefault true;
        }
      ];
    };
  };

  flake.homeModules.graphics = { config, pkgs, lib, ... }: {
    options.features.applications.gui.vscode.enable = lib.mkEnableOption "vscode";

    config = lib.mkIf (config.features.applications.gui.vscode.enable) {
      home.packages = lib.mkIf (config.info.isStandalone) [ pkgs.vscode ];

      home.activation = {
        linkVsCodeConfigSettings = lib.hm.dag.entryAfter ["writeBoundary"] (config.helpers.mkSymlinkActivationScript { 
          target = ".config/Code/User/settings.json";
          source = "dotfiles/global/vscode/settings.json";
        });

        linkVsCodeConfigKeybindings = lib.hm.dag.entryAfter ["writeBoundary"] (config.helpers.mkSymlinkActivationScript { 
          target = ".config/Code/User/keybindings.json";
          source = "dotfiles/global/vscode/keybindings.json";
        });
      };
    };
  };
}