{ inputs, self, ... }: {
  flake.nixosModules.graphics = { config, pkgs, lib, ... }: {
    options.features.applications.gui.vscode.enable = lib.mkEnableOption "vscode";

    config = lib.mkIf (config.features.applications.gui.vscode.enable) (inputs.helpers.mkIfElse (config.features.nixos.home-manager.enable) {
      home-manager.users.grey.features.applications.gui.vscode.enable = lib.mkDefault true;
    } {
      environment.systemPackages = [ pkgs.vscode ];
    });
  };

  flake.homeModules.graphics = { config, pkgs, lib, ... }: {
    options.features.applications.gui.vscode.enable = lib.mkEnableOption "vscode";

    config = lib.mkIf (config.features.applications.gui.vscode.enable) {
      home.packages = [ pkgs.vscode ];

      home.activation = {
        linkVsCodeConfigSettings = lib.hm.dag.entryAfter ["writeBoundary"] (inputs.helpers.mkSymlinkActivationScript { 
          target = "${config.home.homeDirectory}/.config/Code/User/settings.json";
          source = "${config.info.rootPath}/dotfiles/global/vscode/settings.json";
        });

        linkVsCodeConfigKeybindings = lib.hm.dag.entryAfter ["writeBoundary"] (inputs.helpers.mkSymlinkActivationScript { 
          target = "${config.home.homeDirectory}/.config/Code/User/keybindings.json";
          source = "${config.info.rootPath}/dotfiles/global/vscode/keybindings.json";
        });
      };
    };
  };
}