{ inputs, self, ... }: {
  flake.nixosModules.graphics = { config, pkgs, lib, ... }: {
    config = lib.mkIf (builtins.elem "niri" config.components.windowManagers || builtins.elem "biri" config.components.windowManagers) {
      environment.systemPackages = with pkgs; [
        xdg-desktop-portal-gnome
        wl-clipboard
        libsecret
        cage
        wev
      ];

      services.upower.enable = true;

      services.udisks2.enable = true;

      programs.niri = {
        enable = true;
        useNautilus = true;
      };

      home-manager.users.${config.info.userName} = lib.mkIf (config.features.nixos.home-manager.enable) {
        components.windowManagers = [ "niri" ];
      };
    };
  };

  flake.homeModules.graphics = { config, pkgs, lib, inputs, ... }: {
    config = lib.mkIf (builtins.elem "niri" config.components.windowManagers || builtins.elem "biri" config.components.windowManagers) {
      features.applications.gui = {
        kitty.enable = lib.mkForce true;
      };
      
      home.activation = {
        linkNiriConfig = lib.hm.dag.entryAfter ["writeBoundary"] (inputs.helpers.mkSymlinkActivationScript { 
          target = "${config.xdg.configHome}/niri/config.kdl";
          source = "${config.info.rootPath}/dotfiles/${config.info.hostName}/niri.kdl";
        });

        linkSharedNiriConfig = lib.hm.dag.entryAfter ["writeBoundary"] (inputs.helpers.mkSymlinkActivationScript {
          target = "${config.xdg.configHome}/niri/shared.kdl";
          source = "${config.info.rootPath}/dotfiles/shared/niri/shared.kdl";
        });

        linkSharedNoctaliaNiriConfig = lib.mkIf (builtins.elem "noctalia" config.components.shells) (lib.hm.dag.entryAfter ["writeBoundary"] (inputs.helpers.mkSymlinkActivationScript {
          target = "${config.xdg.configHome}/niri/noctalia-shared.kdl";
          source = "${config.info.rootPath}/dotfiles/shared/niri/noctalia-shared.kdl";
        }));

        linkSharedBiriConfig = lib.mkIf (builtins.elem "biri" config.components.windowManagers) (lib.hm.dag.entryAfter ["writeBoundary"] (inputs.helpers.mkSymlinkActivationScript {
          target = "${config.xdg.configHome}/niri/biri-shared.kdl";
          source = "${config.info.rootPath}/dotfiles/shared/niri/biri-shared.kdl";
        }));
      };
    };
  };
}