{ inputs, self, ... }: {
  imports = [ (inputs.helpers.mkMirroredModulesFlakeModule "graphicsOptions" ({ lib, ... }: {
    options.features.nixos.stylix.enable = lib.mkEnableOption "Stylix";
  })) ];

  flake.nixosModules.graphics = { pkgs, lib, config, ... }: {
    imports = [
      inputs.stylix.nixosModules.stylix
    ];

    config = lib.mkIf (config.features.nixos.stylix.enable) {
      stylix.enable = true;
      stylix.image = builtins.path { path = "${self}/modules/hosts/${config.info.hostName}/wallpaper.jpg"; };
      stylix.polarity = "dark";

      home-manager.users.${config.info.userName} = lib.mkIf (config.features.nixos.home-manager.enable) {
        features.nixos.stylix.enable = lib.mkDefault config.features.nixos.stylix.enable;
      };
    };
  };

  flake.homeModules.graphics = { pkgs, lib, config, ... }: {
    config = lib.mkIf (config.features.nixos.stylix.enable) {
      stylix.targets = lib.mkIf (config.features.applications.gui.floorp.enable) {
        floorp.profileNames = [ "default" ];
      };
    };
  };
}