{ inputs, self, ... }: {
  perSystem = { pkgs, ... }: {
    packages = let
      overrideAttrs = with pkgs; finalAttrs: prevAttrs: {
        name = "${finalAttrs.pname}-${finalAttrs.version}";
        pname = "biri";
        version = "26.04";

        src = pkgs.fetchFromGitHub {
          owner = "barrulus";
          repo = finalAttrs.pname;
          rev = "59584af41f34eccc8afdfc05a40b9a7a17bc9c2d";
          hash = "sha256-9vr2VJvDDZP7zfST5TBvVCzOZivdQ+A0cmdURMMD/5w=";
        };

        cargoHash = "sha256-aNovCzrTtmqTO33YtZap47npdN73zXC1bap5q5dZvZk=";

        cargoDeps = rustPlatform.fetchCargoVendor {
          inherit (finalAttrs) pname src version;
          hash = finalAttrs.cargoHash;
        };
      };
    in {
      biri = (pkgs.niri.overrideAttrs (final: prev: overrideAttrs final prev));

      biri-unwrapped = (pkgs.niri.overrideAttrs (final: prev: (overrideAttrs final prev) // {
        postInstall = ''
          install -Dm0644 README.md resources/default-config.kdl -t $doc/share/doc/niri
          mv docs/wiki $doc/share/doc/niri/wiki
          cp -r . $out
        '';
      }));
    };
  };
}