{ ... }: {
  imports = [ ./niri.nix ];

  flake.nixosModules.graphics = { config, pkgs, lib, ... }: {
    # override niri source to use https://github.com/barrulus/biri
    config = lib.mkIf (builtins.elem "biri" config.components.windowManagers) {
      programs.niri.package = pkgs.biri;

      home-manager.users.${config.info.userName} = lib.mkIf (config.features.nixos.home-manager.enable) {
        components.windowManagers = [ "biri" ];
      };
    };
  };

  flake.homeModules.graphics = { config, lib, ... }: {
    config = lib.mkIf (builtins.elem "biri" config.components.windowManagers) {
      features.applications.shellScripts = {
        niri-scratch-workspace-toggle = ''
          if niri msg --json workspaces-with-hidden | jq -e '.[] | select(.name=="x") | .is_hidden' >/dev/null; then
            niri msg action unhide-workspace --focus=false "x"
            OUTPUT=$(niri msg --json focused-output | jq '.name' | sed 's/"//g')
            niri msg action move-workspace-to-monitor --reference "x" "$OUTPUT"
            niri msg action focus-workspace "x"
          else
            niri msg action hide-workspace "x"
          fi
        '';

        niri-listen-for-scratch-workspace-change = ''
          niri msg --json event-stream | while read -r event; do
            if echo $event | jq -e '.WorkspaceActivated.focused' >/dev/null; then
              if niri msg --json workspaces | jq -e '.[] | select(.name=="x") | .is_active==false' >/dev/null; then
                niri msg action hide-workspace "x"
              fi
            elif echo $event | jq -e '.WorkspacesChanged.workspaces.[] | select(.name=="x") | .is_active==false' >/dev/null; then
              niri msg action hide-workspace "x"
            fi
          done
        '';

        niri-toggle-dwt = ''
          niri msg action toggle-dwt
          cd ${config.xdg.stateHome}
          if [ -f ./niri.json ]; then
            if jq -e '.dwt' niri.json >/dev/null; then
              NEW_JSON=$(jq '.dwt = false' niri.json)
              echo "$NEW_JSON" > niri.json
            else
              NEW_JSON=$(jq '.dwt = true' niri.json)
              echo "$NEW_JSON" > niri.json
            fi
          else
            echo '{"dwt": false}' | jq '.' > niri.json
          fi
          PRETTY_STATE=$(if jq -e '.dwt' niri.json >/dev/null; then echo "on"; else echo "off"; fi)
          notify-send -e -a "niri-toggle-dwt script" "Toggled DWT $PRETTY_STATE"
        '';

        niri-clear-state = ''
          cd ${config.xdg.stateHome}
          rm niri.json
        '';
      };
    };
  };
}