{ inputs, self, ... }: {
  imports = [ (inputs.helpers.mkMirroredModulesFlakeModule "gamingOptions" ({ lib, ... }: {
    options.features.hardware.steam-controller.enable = lib.mkEnableOption "tweaks and configurations that assist when using Valve's Steam Controller";
  })) ];

  flake.nixosModules.gaming = { pkgs, config, lib, ... }: {
    config = lib.mkIf (config.features.hardware.steam-controller.enable) {
      hardware.steam-hardware.enable = lib.mkForce true; # most likely enabled somewhere else but should be enforced here regardless

      home-manager.users.${config.info.userName} = lib.mkIf (config.features.nixos.home-manager.enable) {
        features.hardware.steam-controller.enable = lib.mkDefault true;
      };
    };
  };

  flake.homeModules.gaming = { pkgs, config, lib, inputs, ... }: {
    config = let
      pkgsCross = import inputs.nixpkgs {
        localSystem = pkgs.stdenv.hostPlatform.system;
        hostSystem = pkgs.stdenv.hostPlatform.system;
        crossSystem = "i686-linux";
      };
      steam-modified-desktop-file = pkgs.runCommand "modifySteamDesktopFile" {} ''
        sed 's@Exec=/usr/bin/steam@Exec=env LD_PRELOAD=${pkgsCross.extest}/lib/libextest.so /usr/bin/steam@' ${self}/assets/steam.desktop.example > $out
      '';
    in lib.mkIf (config.features.hardware.steam-controller.enable) {
      xdg.dataFile."applications/steam.desktop".source = steam-modified-desktop-file;

      xdg.configFile."autostart/steam.desktop" = {
        source = steam-modified-desktop-file;
        force = true;
      };
    };
  };
}