nix-flake/modules/features/applications/gui/equibop.nix

{ inputs, self, ... }: {
  flake.nixosModules.graphics = { pkgs, lib, config, ...}: {
    options.features.applications.gui.equibop.enable = lib.mkEnableOption "equibop";

    config = let
      mkIfElse = with lib; p: yes: no: mkMerge [
        (mkIf p yes)
        (mkIf (!p) no)
      ];
    in lib.mkIf (config.features.applications.gui.equibop.enable) (mkIfElse (config.features.nixos.home-manager.enable) {
      home-manager.users.grey.features.applications.gui.equibop.enable = lib.mkDefault true;
    } {
      environment.systemPackages = [ pkgs.equibop ];
    });
  };

  flake.homeModules.graphics = { pkgs, lib, config, ... }: {
    options.features.applications.gui.equibop.enable = lib.mkEnableOption "equibop";

    config = lib.mkIf (config.features.applications.gui.equibop.enable) {
      programs.equibop.enable = true;

      home.activation = {
        linkEquibopConfigSettings = lib.hm.dag.entryAfter ["writeBoundary"] (config.helpers.mkSymlinkActivationScript { 
          target = ".config/equibop/settings.json";
          source = "dotfiles/${config.info.hostName}/equibop/settings.json";
        });

        linkEquibopConfigEquicordSettings = lib.hm.dag.entryAfter ["writeBoundary"] (config.helpers.mkSymlinkActivationScript { 
          target = ".config/equibop/settings/settings.json";
          source = "dotfiles/${config.info.hostName}/equibop/equicord-settings.json";
        });

        linkEquibopConfigQuickCss = lib.hm.dag.entryAfter ["writeBoundary"] (config.helpers.mkSymlinkActivationScript { 
          target = ".config/equibop/settings/quickCss.css";
          source = "dotfiles/${config.info.hostName}/equibop/quickCss.css";
        });
      };
    };
  };
}