nix-flake/flake.nix

{
  description = "grey's custom NixOS config";

  inputs = {
    nixpkgs = {
      url = "github:nixos/nixpkgs/nixos-unstable";
    };

    nixpkgs-mesa-overlay = {
      url = "github:nixos/nixpkgs/e4f9df8a27c2b4871c665368e65bdb6852dd93e6";
    };

    home-manager = {
      url = "github:nix-community/home-manager";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    nh = {
      url = "github:nix-community/nh";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    stylix = {
      url = "github:nix-community/stylix";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    zen-browser = {
      url = "github:0xc000022070/zen-browser-flake";
      inputs.nixpkgs.follows = "nixpkgs";
      inputs.home-manager.follows = "home-manager";
    };

    firefox-addons = {
      url = "gitlab:rycee/nur-expressions?dir=pkgs/firefox-addons";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    plasma-manager = {
      url = "github:nix-community/plasma-manager";
      inputs.nixpkgs.follows = "nixpkgs";
      inputs.home-manager.follows = "home-manager";
    };

    noctalia = {
      url = "github:noctalia-dev/noctalia";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    spicetify = {
      url = "github:Gerg-L/spicetify-nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    /*nixos-millennium = {
      url = "git+https://git.greyweather.dev/greyweather/nixos-millennium";
      inputs.nixpkgs.follows = "nixpkgs";
    };*/

    nix-cachyos-kernel = {
      url = "github:xddxdd/nix-cachyos-kernel/release";
    };
  };

  outputs = {self,nixpkgs,nixpkgs-mesa-overlay,home-manager,plasma-manager,stylix,...}@inputs: let
    system = "x86_64-linux";
  in {
    nixosConfigurations = builtins.listToAttrs (map (name: {
      inherit name;
      value = nixpkgs.lib.nixosSystem {
        modules = [
          ./hosts/${name}
          stylix.nixosModules.stylix
          home-manager.nixosModules.default {
            home-manager = {
              useGlobalPkgs = true;
              useUserPackages = true;
              users.grey = ./hosts/${name}/home.nix;
              extraSpecialArgs = {
                inherit inputs;
                hostname = name;
                stateVersion = "26.05";
              };
            };
          }
        ];
        specialArgs = {
          inherit inputs;
          inherit system;
          hostname = name;
          stateVersion = "26.05";
          pkgs-mesa-overlay = import nixpkgs-mesa-overlay {
            inherit system;
            config.allowUnfree = true;
          };
        };
      };
    }) ["takamaki" "kitagawa" "nixos-vm"]);
  };
}